Loader クラス

[内容]

　　SWF ファイルまたはイメージ (JPG，PNG，または，GIF) ファイルをロードするためのクラスです．

継承：　Loader → DisplayObjectContainer → InteractiveObject → DisplayObject → EventDispatcher → Object

[プロパティ]

• content : DisplayObject
  　　 load()，または，loadBytes() メソッドを使用してロードされた SWF ファイルまたはイメージ (JPG，PNG，または，GIF) ファイルのルート表示オブジェクト

• contentLoaderInfo : LoaderInfo
  　　 ロードされているオブジェクトに対応する LoaderInfo オブジェクト．Loarder を使用したロード処理では，Loader オブジェクト自身ではなく，対応する LoaderInfo が各種のイベントを送出する．（使用例参照）

[メソッド]

• Loader()
  　　 コンストラクタ．SWF，JPEG，GIF，または，PNG などのファイルのロードに使用できる Loader オブジェクトを作成

• close():void
  　　 現在進行中の load() メソッドの処理をキャンセル

• load(request:URLRequest, context:LoaderContext = null):void
  　　 SWF，JPEG，GIF，または，PNG などのファイルのロード

• loadBytes(bytes:ByteArray, context:LoaderContext = null):void
  　　 ByteArray オブジェクトに保管されているバイナリデータからロード

• unload():void
  　　 ロードされたオブジェクトを削除

[使用例]

1. 以下に示すのは，「画像を読み込む例」と，そのプログラム（ Loader_e.as ）です．

   package
   {
   	import flash.display.Sprite;
   	import flash.display.Loader;
   	import flash.events.Event;
   	import flash.net.URLRequest;
   	
   	[SWF(backgroundColor="0xeeffee", width="300", height="250", frameRate="30")]
   
   	public class Loader_e extends Sprite
   	{
   		private var ld : Loader;
   
   		public function Loader_e()
   		{
   			init();
   		}
   		
   		private function init():void
   		{
   			ld = new Loader();
   			ld.contentLoaderInfo.addEventListener(Event.INIT, onInit);
   			ld.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
   			ld.load(new URLRequest("hana.gif"));
   			ld.x = 53;
   			ld.y = 23;
   			addChild(ld);
   		}
   
   		private function onInit(event:Event):void
   		{
   			trace("Now Loarding");
   		}
   
   		private function onComplete(event:Event):void
   		{
   			trace("End of Loarding");
   		}
   	}
   }
   			

[参照]

URLRequest クラス， URLLoader クラス