Sprite クラス

[内容]

　　graphics プロパティを持っており，様々な子表示オブジェクトも持つことができます．

継承：　Sprite → DisplayObjectContainer → InteractiveObject → DisplayObject → EventDispatcher → Object

[プロパティ]

• buttonMode : Boolean
  　　ボタンモードを指定．true にすると，ボタンとして動作する．

• dropTarget : DisplayObject
  　　スプライトがドロップされた先の表示オブジェクト

• graphics : Graphics
  　　Graphics オブジェクトを指定

• soundTransform : SoundTransform クラス参照
  　　スプライト内で再生しているサウンドの制御

• useHandCursor : Boolean
  　　ハンドカーソルを表示するか否か

[メソッド]

• Sprite ()
  　　コンストラクタ

• startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void
  　　ドラッグの開始．lockCenter を true にすると，ドラッグオブジェクトがマウス位置の中心にロックされる，false にすると，オブジェクト上で最初にクリックした点にロックされる．また，bounds によって，ドラッグ可能領域を親の座標を基準にした座標系で指定可能である．

• stopDrag():void
  　　ドラッグの終了

[参照]

Graphics クラス， Shape クラス

[使用例]

1. 以下に示すのは，「ドラッグ＆ドロップの例」と，そのプログラム（ Drag_Drop.as ）です．また，buttonMode プロパティと useHandCursor プロパティを使用して，マウスカーソルが円内に入るとハンドカーソルに変わるように設定しています．

   package
   {
   	import flash.display.Sprite;
   	import flash.events.MouseEvent;
   
   	[SWF(backgroundColor="0xeeffee", width="300", height="200", frameRate="30")]
   
   	public class Drag_Drop extends Sprite
   	{
   		private var cir : Sprite;
   
   		public function Drag_Drop()
   		{
   			init();
   		}
   		
   		private function init():void
   		{
   			cir = new Sprite();
   			cir.graphics.beginFill(0xff00ff00);
   			cir.graphics.drawCircle(150, 100, 50);
   			cir.graphics.endFill();
   			cir.buttonMode = true;
   			cir.useHandCursor = true;
   			addChild(cir);
   
   			cir.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
   		}
   
   		private function onMouseDown(event:MouseEvent):void
   		{
   			cir.startDrag();
   			cir.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   			stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
   		}
   
   		private function onMouseMove(event:MouseEvent):void
   		{
   			event.updateAfterEvent();
   		}
   
   		private function onMouseUp(event:MouseEvent):void
   		{
   			cir.stopDrag();
   			cir.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   			stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);
   		}
   	}
   }
   			

[参照]

Graphics クラス， SoundTransform クラス