KeyboardEvent クラス

[内容]

　　キーボードイベントに対する処理を行うクラスです．

継承：　KeyboardEvent → Event → Object

[プロパティ]

• altKey : Boolean
  　　Alt キーがアクティブになっているか否か

• charCode : uint
  　　文字コード

• ctrlKey : Boolean
  　　ctrl キーがアクティブになっているか否か

• keyCode : uint
  　　キーコード

• keyLocation : uint
  　　キーボード上のキーの場所．たとえば，以下のようなキーの識別に利用される．
  • KeyLocation.LEFT， KeyLocation.RIGHT ： 左右の Shift キー
  • KeyLocation.STANDARD，KeyLocation.NUM_PAD ： 数字キーとテンキー

• shiftKey : Boolean
  　　Shift キーがアクティブになっているか否か

[メソッド]

• updateAfterEvent():void
  　　 表示リストが変更されている場合は，イベント終了処理の後にレンダリングを指示

[定数]　　すべて static

• KEY_DOWN : String = "keyDown"
  　　keyDown イベントオブジェクト

• KEY_UP : String = "keyUp"
  　　keyUp イベントオブジェクト

[使用例]

1. 「キーボードイベントの例」と，そのプログラム（ KeyboardEvent_e.as ）です．「 n キー」でフォーカスが切り替わります．

   package
   {
   	import flash.display.Sprite;
   	import flash.events.KeyboardEvent;
   
   	[SWF(backgroundColor="0x000000", width="300", height="200", frameRate="30")]
   
   	public class KeyboardEvent_e extends Sprite
   	{
   		private var rect : Sprite;
   		private var cir : Sprite;
   
   		public function KeyboardEvent_e()
   		{
   			init();
   		}
   		
   		private function init():void
   		{
   			stage.stageFocusRect = true;
   
   			rect = new Sprite();
   			rect.graphics.beginFill(0xffff0000);
   			rect.graphics.drawRect(60, 60, 80, 80);
   			rect.graphics.endFill();
   			rect.name = "rectangle";
   			addChild(rect);
   
   			cir = new Sprite();
   			cir.graphics.beginFill(0xff00ff00);
   			cir.graphics.drawCircle(200, 100, 40);
   			cir.graphics.endFill();
   			cir.name = "circle";
   			addChild(cir);
   
   			stage.focus = rect;
   			stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
   		}
   
   		private function onKeyDown(event:KeyboardEvent):void {
   			if (event.keyCode == 78) {
   				if (event.target.name == "rectangle")
   					stage.focus = cir;
   				else
   					stage.focus = rect;
   			}
   		}
   	}
   }