MouseEvent クラス

[内容]

　　マウスイベントに対する処理を行うクラスです．

継承：　MouseEvent → Event → Object

[プロパティ]

• altKey : Boolean
  　　Alt キーがアクティブになっているか否か

• buttonDown : Boolean
  　　マウスの主ボタンが押されているか否か

• ctrlKey : Boolean
  　　Ctrl キーがアクティブになっているか否か

• delta : int
  　　マウスホイールを 1 目盛り回すごとにスクロールする行数

• localX : Number
  　　スプライトを基準とするイベント発生位置の x 座標

• localY : Number
  　　スプライトを基準とするイベント発生位置の y 座標

• relatedObject : InteractiveObject
  　　イベントを発生した表示リストオブジェクト．mouseOut イベントと mouseOver イベントだけに適用

• shiftKey : Boolean
  　　Shift キーがアクティブになっているか否か

• stageX : Number
  　　イベント発生位置の x 座標

• stageY : Number
  　　イベント発生位置の y 座標

[メソッド]

• updateAfterEvent():void
  　　 表示リストが変更されている場合は，イベント終了処理の後にレンダリングを指示

[定数]　　すべて static

• CLICK : String = "click"
  　　click イベントオブジェクト

• DOUBLE_CLICK : String = "doubleClick"
  　　doubleClick イベントオブジェクト

• MOUSE_DOWN : String = "mouseDown"
  　　mouseDown イベントオブジェクト

• MOUSE_MOVE : String = "mouseMove"
  　　mouseMove イベントオブジェクト

• MOUSE_OUT : String = "mouseOut"
  　　mouseOut イベントオブジェクト

• MOUSE_OVER : String = "mouseOver"
  　　mouseOver イベントオブジェクト

• MOUSE_UP : String = "mouseUp"
  　　mouseUp イベントオブジェクト

• MOUSE_WHEEL : String = "mouseWheel"
  　　mouseWheel イベントオブジェクト

• ROLL_OUT : String = "rollOut"
  　　rollOut イベントオブジェクト

• ROLL_OVER : String = "rollOver"
  　　rollOver イベントオブジェクト

[使用例]

1. 「この例」では，マウスが矩形または円の内部に入るとその図形にフォーカスされます．以下はそのプログラム（ MouseEvent_focus.as ）です．

   package
   {
   	import flash.display.Sprite;
   	import flash.events.MouseEvent;
   
   	[SWF(backgroundColor="0x000000", width="300", height="200", frameRate="30")]
   
   	public class MouseEvent_focus extends Sprite
   	{
   		private var rect : Sprite;
   		private var cir : Sprite;
   
   		public function MouseEvent_focus()
   		{
   			init();
   		}
   		
   		private function init():void
   		{
   			stage.stageFocusRect = true;
   
   			rect = new Sprite();
   			rect.graphics.beginFill(0xffff0000);
   			rect.graphics.drawRect(60, 60, 80, 80);
   			rect.graphics.endFill();
   			rect.name = "rectangle";
   			addChild(rect);
   
   			cir = new Sprite();
   			cir.graphics.beginFill(0xff00ff00);
   			cir.graphics.drawCircle(200, 100, 40);
   			cir.graphics.endFill();
   			cir.name = "circle";
   			addChild(cir);
   
   			stage.focus = rect;
   			rect.addEventListener(MouseEvent.ROLL_OUT, onRollOut);
   			rect.addEventListener(MouseEvent.ROLL_OVER, onRollOver);
   			cir.addEventListener(MouseEvent.ROLL_OUT, onRollOut);
   			cir.addEventListener(MouseEvent.ROLL_OVER, onRollOver);
   		}
   
   		private function onRollOut(event:MouseEvent):void {
   			stage.focus = null;
   		}
   
   		private function onRollOver(event:MouseEvent):void {
   			if (event.target.name == "rectangle")
   				stage.focus = rect;
   			else
   				stage.focus = cir;
   		}
   	}
   }