Array クラス

[内容]

　　配列の処理を行うためのクラスです．

継承：　Array → Object

[定数]　　すべて，static

• CASEINSENSITIVE : uint = 1
  　　大文字と小文字を区別しないソートを指定

• DESCENDING : uint = 2
  　　数値によるソートを指定

• NUMERIC : uint = 16
  　　文字ストリングではなくす

• RETURNINDEXEDARRAY : uint = 8
  　　ソート結果として，配列インデックスで構成される配列を返すことを指定（ソート対象の配列は変更されない）

• UNIQUESORT : uint = 4
  　　一意性ソート要件を指定（同じデータが複数ある場合は，値 0 が返され，ソート対象の配列は変更されない）

[プロパティ]

• length : uint
  　　配列内の要素数

[メソッド]

• Array(numElements:int = 0)
  　　指定された数の要素を持つ配列を作成

• Array(... values)
  　　指定された要素を持つ配列を作成

• concat(... args):Array
  　　パラメータで指定された要素を配列内の要素と連結して，新しい配列を作成（使用例１）

• every(callback:Function, thisObject:* = null):Boolean
  　　指定されたテスト関数が false を返す要素に達するまで，配列内の各要素にテスト関数を実行する．2 番目の引数は，テスト関数内で this が参照するオブジェクトを指定したいときに使用する．テスト関数には，（要素の値，要素のインデックス，配列）という 3 つのパラメータが渡される．（使用例２）

• filter(callback:Function, thisObject:* = null):Array
  　　配列内の各要素に対してテスト関数を実行し，テスト関数が true を返すすべての要素を含む新しい配列を作成する．2 番目の引数は，テスト関数内で this が参照するオブジェクトを指定したいときに使用する．テスト関数には，（要素の値，要素のインデックス，配列）という 3 つのパラメータが渡される．（使用例２）

• forEach(callback:Function, thisObject:* = null):void
  　　配列内の各要素に対してテスト関数を実行する．2 番目の引数は，テスト関数内で this が参照するオブジェクトを指定したいときに使用する．テスト関数には，（要素の値，要素のインデックス，配列）という 3 つのパラメータが渡される．（使用例２）

• indexOf(searchElement:*, fromIndex:int = 0):int
  　　厳密な等価 (===) を使用して配列内の要素を検索し，要素のインデックスを返す（使用例１）

• join(sep:*):String
  　　配列内の要素を文字列に変換し，指定されたセパレータを要素間に挿入し，各要素を連結した結果を返す（使用例１）

• lastIndexOf(searchElement:*, fromIndex:int = 0x7fffffff):int
  　　厳密な等価 (===) を使用して配列内の要素を後方から検索し，要素のインデックスを返す（使用例１）

• map(callback:Function, thisObject:* = null):Array
  　　配列内の各要素に対してテスト関数を実行し，その結果を配列として返す．2 番目の引数は，テスト関数内で this が参照するオブジェクトを指定したいときに使用する．テスト関数には，（要素の値，要素のインデックス，配列）という 3 つのパラメータが渡される．（使用例２）

• pop():*
  　　配列の最後の要素を削除して，その要素の値を返す（使用例１）

• push(... args):uint
  　　要素を配列の最後に追加して，配列の長さを返す（使用例１）

• reverse():Array
  　　配列の並びを反転させる（使用例３）

• shift():*
  　　配列の最初の要素を削除して，その要素の値を返す（使用例１）

• slice(startIndex:int = 0, endIndex:int = 16777215):Array
  　　配列から一連の要素を取り出して，それらの要素からなる新しい配列を返す．元の配列は変更されない．（使用例１）

• some(callback:Function, thisObject:* = null):Boolean
  　　指定されたテスト関数が true を返す要素に達するまで，配列内の各要素にテスト関数を実行する．2 番目の引数は，テスト関数内で this が参照するオブジェクトを指定したいときに使用する．テスト関数には，（要素の値，要素のインデックス，配列）という 3 つのパラメータが渡される．（使用例２）

• sort([[compareFunction:Function][, sortOptions:Object]]):Array
  　　配列内の要素をソートする．比較関数には，比較を行うために 2 つの引数が必要であり，-1，0，または，1 を返す．また，ソートオプションでは，デフォルトのソート動作を変更する数値または定義済み定数を記述する．複数指定する場合は，ビット単位の論理和 (OR) | 演算子で区切って指定する．（使用例３）

• sortOn(fieldName:Object, options:Object = null):Array
  　　配列内の要素がオブジェクトで有り，すべての要素が共通のフィールド（プロパティ）を持っている場合，そのフィールドに基づいてソートする．複数のフィールドを対象とする場合は，([fieldName1, fieldName2, ...],[options1, options2, ...]) のように記述する．（使用例３）

• splice(startIndex:int, deleteCount:uint, ... values):Array
  　　配列から一連の要素を削除し，その箇所に新しい要素を追加する．元の配列は変化する．（使用例１）

• toString():String
  　　配列内のすべての要素を，カンマで区切られた文字列に変換して返す（使用例１）

• unshift(... args):uint
  　　要素を配列の先頭に追加して，配列の長さを返す（使用例１）

[使用例]

1. 使用例１： concat，indexOf, lastIndexOf，pop，push，shift，unshift，slice，splice，join，toString　->　表示とそのソースコード

   ackage {
   	import flash.display.Sprite;
   
   	[SWF(backgroundColor="0xeeffee", width="500", height="200", frameRate="30")]
   
   	public class Array_e1 extends Sprite {
   
   		public function Array_e1() {
   			var msg : Message = new Message(500, 100);
   			addChild(msg);
   			var a : Array = new Array(1.5, 2.3, 3.4, 2.3);
   			var i1 : int;
   			var p1 : int;
   			var p2 : int;
   			var str : String;
   					// concat
   			var b : Array = a.concat(-1.0, -2.5);
   			msg.tx.appendText("concat(b) : ");
   			for (i1 = 0; i1 < b.length; i1++)
   				msg.tx.appendText(b[i1] + " ");
   			msg.tx.appendText("\n");
   					// indexOf, lastIndexOf
   			p1 = b.indexOf(2.3);
   			p2 = b.lastIndexOf(2.3);
   			msg.tx.appendText("indexOf: " + p1 + ", lawstIndexOf: " + p2 + "\n");
   					// pop
   			b.pop();
   			b.pop();
   			msg.tx.appendText("pop(b) : ");
   			for (i1 = 0; i1 < b.length; i1++)
   				msg.tx.appendText(b[i1] + " ");
   			msg.tx.appendText("\n");
   					// push
   			b.push(-1.0, -2.5);
   			msg.tx.appendText("push(b) : ");
   			for (i1 = 0; i1 < b.length; i1++)
   				msg.tx.appendText(b[i1] + " ");
   			msg.tx.appendText("\n");
   					// shift
   			b.shift();
   			b.shift();
   			msg.tx.appendText("shift(b) : ");
   			for (i1 = 0; i1 < b.length; i1++)
   				msg.tx.appendText(b[i1] + " ");
   			msg.tx.appendText("\n");
   					// unshift
   			b.unshift(1.5, 2.3);
   			msg.tx.appendText("unshift(b) : ");
   			for (i1 = 0; i1 < b.length; i1++)
   				msg.tx.appendText(b[i1] + " ");
   			msg.tx.appendText("\n");
   					// slice
   			var c : Array = b.slice(3, 5);
   			msg.tx.appendText("slice : ");
   			for (i1 = 0; i1 < c.length; i1++)
   				msg.tx.appendText(c[i1] + " ");
   			msg.tx.appendText("\n");
   					// splice
   			var d : Array = b.splice(0, 3, 20, 10);
   			msg.tx.appendText("splice : ");
   			for (i1 = 0; i1 < d.length; i1++)
   				msg.tx.appendText(d[i1] + " ");
   			msg.tx.appendText("\n");
   					// join
   			str = b.join(";");
   			msg.tx.appendText("join : " + str + "\n");
   					// toString
   			str = b.toString();
   			msg.tx.appendText("toString : " + str + "\n");
   		}
   	}
   }
   
   package
   {
   	import flash.display.Sprite;
   	import flash.text.TextField;
   	import flash.text.TextFieldType;
   	import flash.text.TextFormat;
   	import flash.text.TextFormatAlign;
   	import flash.events.MouseEvent;
   
   	public class Message extends Sprite
   	{
   		public var tx : TextField;
   		public function Message(w : int, h : int)
   		{
   			tx = new TextField();
   			tx.width = w;
   			tx.height = h;
   			tx.x = 0;
   			tx.y = 0;
   			tx.type = TextFieldType.DYNAMIC;
   			tx.background = true;
   			tx.backgroundColor = 0xffffff;
   			tx.border = true;
   			tx.borderColor = 0x00ff00;
   			tx.multiline = true;
   			var tf : TextFormat = new TextFormat();
   			tf.size = 20;
   			tx.defaultTextFormat = tf;
   			addChild(tx);
   			addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
   		}
   
   		private function onMouseDown(event:MouseEvent):void
   		{
   			startDrag();
   			addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   			stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
   		}
   
   		private function onMouseMove(event:MouseEvent):void
   		{
   			event.updateAfterEvent();
   		}
   
   		private function onMouseUp(event:MouseEvent):void
   		{
   			stopDrag();
   			removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   			stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);
   		}
   	}
   }
   			

2. 使用例２： forEach，map，every，some，filter　->　表示とそのソースコード

   package {
   	import flash.display.Sprite;
   
   	[SWF(backgroundColor="0xeeffee", width="500", height="200", frameRate="30")]
   
   	public class Array_e2 extends Sprite {
   
   		public function Array_e2() {
   			var msg : Message = new Message(500, 100);
   			addChild(msg);
   			var a : Array = new Array(1, 2, 3, -1, -2, 20, 10);
   			var b : Array = new Array(1, 2, 3, 2, 1);
   			var i1 : int;
   					// forEach
   			msg.tx.appendText("forEach(a) : ");
   			a.forEach(check2);
   			msg.tx.appendText("\n");
   			msg.tx.appendText("forEach(b) : ");
   			b.forEach(check2);
   			msg.tx.appendText("\n");
   					// map
   			msg.tx.appendText("map(a) : ");
   			var d : Array = a.map(check3);
   			for (i1 = 0; i1 < d.length; i1++)
   				msg.tx.appendText(d[i1] + " ");
   			msg.tx.appendText("\n");
   					// every
   			var ra : String = a.every(check1).toString();
   			var rb : String = b.every(check1).toString();
   			msg.tx.appendText("every : a:" + ra + ", b:" + rb + "\n");
   					// some
   			ra = a.some(check1).toString();
   			rb = b.some(check1).toString();
   			msg.tx.appendText("some : a:" + ra + ", b:" + rb + "\n");
   					// filter
   			var c : Array = a.filter(check1);
   			msg.tx.appendText("filter : ");
   			for (i1 = 0; i1 < c.length; i1++)
   				msg.tx.appendText(c[i1] + " ");
   			msg.tx.appendText("\n");
   
   			function check1(item:*, index:int, array:Array):Boolean
   			{
   				return item > 0;
   			}
   
   			function check2(item:*, index:int, array:Array):void
   			{
   				msg.tx.appendText(item + " ");
   			}
   
   			function check3(item:*, index:int, array:Array):int
   			{
   				return item;
   			}
   		}
   	}
   }
   
   package
   {
   	import flash.display.Sprite;
   	import flash.text.TextField;
   	import flash.text.TextFieldType;
   	import flash.text.TextFormat;
   	import flash.text.TextFormatAlign;
   	import flash.events.MouseEvent;
   
   	public class Message extends Sprite
   	{
   		public var tx : TextField;
   		public function Message(w : int, h : int)
   		{
   			tx = new TextField();
   			tx.width = w;
   			tx.height = h;
   			tx.x = 0;
   			tx.y = 0;
   			tx.type = TextFieldType.DYNAMIC;
   			tx.background = true;
   			tx.backgroundColor = 0xffffff;
   			tx.border = true;
   			tx.borderColor = 0x00ff00;
   			tx.multiline = true;
   			var tf : TextFormat = new TextFormat();
   			tf.size = 20;
   			tx.defaultTextFormat = tf;
   			addChild(tx);
   			addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
   		}
   
   		private function onMouseDown(event:MouseEvent):void
   		{
   			startDrag();
   			addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   			stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
   		}
   
   		private function onMouseMove(event:MouseEvent):void
   		{
   			event.updateAfterEvent();
   		}
   
   		private function onMouseUp(event:MouseEvent):void
   		{
   			stopDrag();
   			removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   			stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);
   		}
   	}
   }
   			

3. 使用例３： reverse，sort，sortOn　->　表示とそのソースコード

   package {
   	import flash.display.Sprite;
   
   	[SWF(backgroundColor="0xeeffee", width="500", height="200", frameRate="30")]
   
   	public class Array_e3 extends Sprite {
   
   		public function Array_e3() {
   			var msg : Message = new Message(500, 100);
   			addChild(msg);
   			var a : Array = new Array(1, 5, 3, 0);
   			var i1 : int;
   					// reverse
   			a.reverse();
   			msg.tx.appendText("reverse : ");
   			for (i1 = 0; i1 < a.length; i1++)
   				msg.tx.appendText(a[i1] + " ");
   			msg.tx.appendText("\n");
   					// sort（昇順）
   			a.sort();
   			msg.tx.appendText("sort（昇順） : ");
   			for (i1 = 0; i1 < a.length; i1++)
   				msg.tx.appendText(a[i1] + " ");
   			msg.tx.appendText("\n");
   					// sort（降順，ソートオプション）
   			a.sort(Array.DESCENDING);
   			msg.tx.appendText("sort（降順，ソートオプション） : ");
   			for (i1 = 0; i1 < a.length; i1++)
   				msg.tx.appendText(a[i1] + " ");
   			msg.tx.appendText("\n");
   					// sort（降順，比較関数）
   			a.sort(comp);
   			msg.tx.appendText("sort（降順，比較関数） : ");
   			for (i1 = 0; i1 < a.length; i1++)
   				msg.tx.appendText(a[i1] + " ");
   			msg.tx.appendText("\n");
   					// sortOn
   			var b : Array = new Array(3);
   			b.push(new Complex(19.2, 1.2));
   			b.push(new Complex(1.7, 4.5));
   			b.push(new Complex(3.5, 10.5));
   			b.sortOn("real", Array.NUMERIC);
   			msg.tx.appendText("sortOn : \n");
   			for (i1 = 0; i1 < b.length; i1++)
   				msg.tx.appendText("   (" + b[i1].real + ", " + b[i1].img + ")\n");
   
   			function comp(a:int, b:int):int
   			{
   				return b - a;
   			}
   		}
   	}
   }
   
   package {
   	public class Complex {
   		public var real : Number;
   		public var img : Number;
   		public function Complex(x:Number, y:Number) {
   			this.real = x;
   			this.img  = y;
   		}
   	}
   }
   
   package
   {
   	import flash.display.Sprite;
   	import flash.text.TextField;
   	import flash.text.TextFieldType;
   	import flash.text.TextFormat;
   	import flash.text.TextFormatAlign;
   	import flash.events.MouseEvent;
   
   	public class Message extends Sprite
   	{
   		public var tx : TextField;
   		public function Message(w : int, h : int)
   		{
   			tx = new TextField();
   			tx.width = w;
   			tx.height = h;
   			tx.x = 0;
   			tx.y = 0;
   			tx.type = TextFieldType.DYNAMIC;
   			tx.background = true;
   			tx.backgroundColor = 0xffffff;
   			tx.border = true;
   			tx.borderColor = 0x00ff00;
   			tx.multiline = true;
   			var tf : TextFormat = new TextFormat();
   			tf.size = 20;
   			tx.defaultTextFormat = tf;
   			addChild(tx);
   			addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
   		}
   
   		private function onMouseDown(event:MouseEvent):void
   		{
   			startDrag();
   			addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   			stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
   		}
   
   		private function onMouseMove(event:MouseEvent):void
   		{
   			event.updateAfterEvent();
   		}
   
   		private function onMouseUp(event:MouseEvent):void
   		{
   			stopDrag();
   			removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
   			stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);
   		}
   	}
   }